Textmarker Toggle Text hervorheben in Word

Neuer Shortcut zum Hervorheben mit Textmarker ab Word 2010

Mit Word 2010 hat Microsoft auf die Nutzer reagiert. Seitdem gibt es einen Shortcut: Mit Strg + Alt + H lässt sich die Hervorhebung für das markierte Wort bzw. den markierten Bereich aus- und einschalten, also toggeln. Dabei wird die Farbe verwendet, die zuletzt auf der Textmarkerpalette ausgewählt war. Damit braucht man die unten stehende Makrolösung seit Word 2010 nicht mehr unbedingt.

Ich nutze das unten stehende Makro weiter, um grundsätzlich gelb hervorzuheben, und zwar unabhängig von der auf der Textmarkerpalette eingestellten Farbe. Bei mir liegt das Makro Erweiterter Toggle Textmarker auf dem Shortcut: Alt + H. Um die Farbe auf der Textmarkerpalette zu verwenden, hat man zusätzlich den neuen Shortcut Strg + Alt + H. Damit hat man wenigstens zwei Farben per Shortcut für die Textmarker-Hervorhebung in Word verfügbar.

Lösung Textmarker Toggle hervorheben in Word 97 bis Word 2007

Der in Word vorhandene Textmarker lässt sich leider nicht mit einem Toggle bedienen. Wechselt man ins Menü Format – Hervorheben oder verwendet die Symbolschaltfläche Textmarker, wird die vorher eingestellte Farbe verwendet. Will man die Hervorhebung wieder aufheben, muss man zunächst die Farbe auf »Keine« ändern und dann den Text markieren und die Farbe entfernen.

Die folgende kleine Prozedur hebt markierten Text gelb hervor oder hebt die Markierung auf, falls der Text vorher markiert war – unabhängig davon, in welcher Farbe. Auch die Einstellung der Farbe in der Symbolleistenauswahl wird nicht beeinflusst. Man kann den Code mit einem → Shortcut versehen oder auf eine eigene → Schaltfläche in der Menüleiste legen.

Einfacher Toggle für die Textmarker-Hervorhebung (ab Word 97)

Sub MarkiertenTextHervorheben()  
' Toggle schaltet die Hervorhebung ein/aus, und zwar immer gelb,  
' unabhängig von der Farbe auf dem Stift in der Menüleiste
' © Schreibbüro Nora Richter

    If Not Selection.Type = wdSelectionNormal Then
        Application.StatusBar = "Es ist kein Text markiert!"
        Exit Sub  
    End If

    With Selection.Range
        If .HighlightColorIndex = wdAuto Then
            .HighlightColorIndex = wdYellow
        Else
            .HighlightColorIndex = wdAuto
        End If
    End With
    Selection.Collapse wdCollapseEnd

End Sub  

Erweiterter Textmarker Toggle zum Hervorheben ohne vorherige Markierung

In Word 97 musste ein Wort nicht markiert sein, um es mit dem Textmarker hervorzuheben. Es reichte aus, wenn der Cursor innerhalb eines Wortes stand. Dieses Verhalten bildet die erweiterte Prozedur unten für Word-Versionen ab Word 2000 nach: Steht der Cursor im Wortinneren und man löst das Makro mittels Shortcut aus, wird das Wort gelb markiert. Sind bereits ein oder mehrere Wörter oder Absätze markiert und man löst das Makro aus, wird der markierte Bereich gelb hervorgehoben bzw. die Hervorhebung wieder entfernt.

Sub Wort_oder_markiertenTextHervorheben()  
' Toggle schaltet die Hervorhebung ein/aus, und zwar immer gelb,
' unabhängig von der Farbe auf dem Stift in der Menüleiste
' markiert auch, wenn der Cursor innerhalb eines Wortes steht
' © Schreibbüro Nora Richter

    Dim lngAnfang As Long
    Dim lngEnde As Long
    Dim rng As Word.Range
    Dim bSel As Boolean
      
    Set rng = Selection.Range.Duplicate
    bSel = False
 
    If Selection.Type = wdSelectionIP Then
        If Val(Application.Version) > 8 Then
            'bildet das Verhalten von Word 97 nach
            bSel = True
            lngAnfang = rng.Start
            lngEnde = rng.End
            rng.Expand wdWord
            If rng.Characters.Last = " " Then
                rng.MoveEnd Unit:=wdCharacter, Count:=-1
            End If
        End If
    End If

    If rng.HighlightColorIndex = wdAuto Then
        rng.HighlightColorIndex = wdYellow
    Else
        rng.HighlightColorIndex = wdAuto
    End If

    If bSel Then
        rng.SetRange Start:=lngAnfang, End:=lngEnde
        rng.Select
    Else
        rng.Collapse wdCollapseEnd
    End If

End Sub

Soll Text häufig in verschiedenen Farben hervorgehoben werden, können Sie die fertige → Textmarker-Symbolleiste verwenden, die alle Farben bequem bereithält und sich bis Word 2003 frei auf dem Bildschirm anordnen lässt.