Schreibbüro Richter

Eine beliebige Frist in Word setzen, ohne einen Kalender zu verwenden

Beim Schreiben von Geschäftspost in Word benötigt man häufig ein Datum in der Zukunft. Man wünscht sich ein Datumsfeld + X Tage, um beispielsweise bei einer Mahnung eine Frist von 14 Tagen zu setzen. Leider ist das Rechnen mit Feldfunktionen in Word für Datumsangaben nicht geeignet. Um dabei nicht jedesmal erst einen Kalender aufrufen zu müssen, kann man das folgende Makro verwenden. Es fragt zunächst die Länge der gewünschten Frist ab. Die Frist wird automatisch berechnet und das Datum eingefügt. Dabei wird auch sichergestellt, dass die Frist an einem Wochentag abläuft.

VBA-Fristmakro


Sub Fristdatum()  
 'fügt ein Datum in der Zukunft ein  

    Dim strWieviel As String
    Dim dateFrist As Date
    strWieviel = InputBox(Prompt:="Wie viele Tage sollen addiert werden?", _
                          Title:="Automatisches Fristdatum von Nora Richter")
    If strWieviel = "" Then Exit Sub  
    If IsNumeric(strWieviel) = False Then
        MsgBox "Sie haben keine Zahl eingegeben." & vbCrLf & _
               "Die Prozedur wird abgebrochen."
        Exit Sub
    End If

    dateFrist = DateAdd("d", strWieviel, Date)

    Select Case Weekday(dateFrist)
     ' stellt sicher, dass die Frist immer an einem Wochentag endet  
        Case Is = vbSaturday
            dateFrist = DateAdd("d", 2, dateFrist)
        Case Is = vbSunday
            dateFrist = DateAdd("d", 1, dateFrist)
    End Select

    Selection.InsertAfter Format$(dateFrist, "d. mmmm yyyy")
    Selection.Collapse wdCollapseEnd

End Sub  

So ordnen Sie dem Makro eine Schaltfläche oder einen Shortcut zu: → Tutorial: VBA-Code für Makro einbringen und verwenden.